Comment periodic Burgers-like, infinite-D coord transform. 
Written in Reduce, see https://reduce-algebra.sourceforge.io/
AJR, 11 Jun 2019;
on div; off allfac; on revpri; 
clear sum;

operator xx; depend xx,t;
let df(xx(~i),t)=>sub(j=i,dxxjdt);
operator a; write "a(j) for eigenvalues alpha_j";
operator b; write "b(j,k)=k*(j-k)";
let b(j,j-~k)=>b(j,k);
factor o;

operator sum; linear sum;
let df(sum(~a,~b),~t)=>sum(df(a,t),b);

operator d;
write "d(j,k)=1/(-a(j)+a(k)+a(j-k))=1/(n^2+2*j*k-2k^2)";
write "d(j,k,l)=1/(-a(j)+a(k)+a(l-k)+a(j-l))
        =1/2/(n^2+j*l+k*l-k^2-l^2)";
let { d(j,k)*a(k) => 1-d(j,k)*(-a(j)+a(j-k))
    , d(j,k,l)*a(k) => 1-d(j,k)*(-a(j)+a(l-k)+a(j-l))
    };

write "Linear approx evolution";
xj:=xx(j);
dxxjdt:=a(j)*xx(j); 

write "Quadratic solution shape";
let o^2=>0;% order of error
xj:=xj+o/2*sum(b(j,k)*(d(j,k)*t-d(j,k)^2)*xx(k)*xx(j-k),k);
resj:=-df(xj,t)+a(j)*xj
    +o*t/2*sum(b(j,l)*sub(j=l,xj)*sub(j=j-l,xj),l);
resj:=sub(l=k,resj);

write "However, zero divisors occur in d(j,k)
=1/(-a(j)+a(k)+a(j-k)) =1/(n^2+2*j*k-2k^2).  But not for odd
n.  For even n>0, find that zero divisors come from all the
factors of n^2/2 since divisor=0 rewrites as k(k-j)=n^2/2. 
Both the positive and negative factors contribute.  For
example, n=2 gives n^2/2=2 with factors 2,1 and -2,-1 and
1,2 and -1,-2.  So zero divisor for k=2,j=1 and k=-2,j=-1
and k=1,j=-1 and k=-1,j=1.";

write "Cubic manifold shape---pv. zero divisors are avoided
in the quadratic terms by perhaps requiring n be odd.";
let o^3=>0;% order of error
resj:=-df(xj,t)+a(j)*xj
    +o*t/2*sum(b(j,l)*sub(j=l,xj)*sub(j=j-l,xj),l)$
depend k,kl; depend l,kl;
resj:=(resj where sum(~~a*sum(~b,~l),~k)=>sum(a*b,kl))$
resj:=(resj where sum(~b,l)=>sum(sub(l=k,b),k))$
resj:=(resj where sum(~a,kl)=>sum(sub(l=j-l,a),kl) 
    when df(a,xx(l)) neq 0)$
write "Extract the coefficient of X(j-l)X(l-k)X(k)";
rhsjkl:=(resj where sum(~a,kl) => coeffn( coeffn( coeffn(
    a,xx(k),1) ,xx(j-l),1) ,xx(l-k),1));
write "Iterative soln of ODE for coeff---zero divisors excluded";
cjkl:=0;
for it:=1:9 do begin
  write resc:=d(j,k,l)*(rhsjkl-df(cjkl,t))-cjkl;
  cjkl:=cjkl+resc;
  if resc=0 then write "success ",it:=10000+it;
end;
cjkl:=cjkl;
write "Update the xj";
xj:=xj+sum(cjkl*xx(j-l)*xx(l-k)*xx(k),kl);

write "But some RHS resonante and so must be in the
evolution instead. Need definite r so set ",n:=1, 
"Explore coefficients to a max wavenumber of ",maxj:=10,
"The negative j cases are the same with k, l, j-l and l-k
all also changed sign.  It looks like that to get dxx(j)
correct then we need maxj=j+3, but could be different for
n>1, guess perhaps maxj=j+3*n?";
r:=n^2; 
o:=1; % remove order symbol
factor xx;
% to get substitution have to change variables!
rhsjkl:=(rhsjkl where { b(l,k)=>kk*(ll-kk)
    , b(j,l)=>ll*(jj-ll)
    , d(l,k)=>1/(r+2*ll*kk-2*kk^2) })$
% Now sum over all contributions to dXj/dt
array dxx(maxj); 
for j:=0:maxj do write dxx(j):= (r-j^2)*xx(j)+
    for k:=-maxj:maxj sum for l:=-maxj:maxj sum
    if n^2+j*l+k*l-k^2-l^2=0
    then sub({jj=j,kk=k,ll=l},rhsjkl)*xx(j-l)*xx(l-k)*xx(k)
    else 0;

end;